mirror of
https://github.com/starr-dusT/yuzu-mainline
synced 2024-03-05 21:12:25 -08:00
cdb240f3d4
[REUSE] is a specification that aims at making file copyright information consistent, so that it can be both human and machine readable. It basically requires that all files have a header containing copyright and licensing information. When this isn't possible, like when dealing with binary assets, generated files or embedded third-party dependencies, it is permitted to insert copyright information in the `.reuse/dep5` file. Oh, and it also requires that all the licenses used in the project are present in the `LICENSES` folder, that's why the diff is so huge. This can be done automatically with `reuse download --all`. The `reuse` tool also contains a handy subcommand that analyzes the project and tells whether or not the project is (still) compliant, `reuse lint`. Following REUSE has a few advantages over the current approach: - Copyright information is easy to access for users / downstream - Files like `dist/license.md` do not need to exist anymore, as `.reuse/dep5` is used instead - `reuse lint` makes it easy to ensure that copyright information of files like binary assets / images is always accurate and up to date To add copyright information of files that didn't have it I looked up who committed what and when, for each file. As yuzu contributors do not have to sign a CLA or similar I couldn't assume that copyright ownership was of the "yuzu Emulator Project", so I used the name and/or email of the commit author instead. [REUSE]: https://reuse.software Follow-up to 01cf05bc75b1e47beb08937439f3ed9339e7b254
37 lines
1.3 KiB
CMake
37 lines
1.3 KiB
CMake
# SPDX-FileCopyrightText: 2020 yuzu Emulator Project
|
|
# SPDX-License-Identifier: GPL-2.0-or-later
|
|
|
|
set(SOURCE_FILE ${CMAKE_ARGV3})
|
|
set(HEADER_FILE ${CMAKE_ARGV4})
|
|
set(INPUT_FILE ${CMAKE_ARGV5})
|
|
|
|
get_filename_component(CONTENTS_NAME ${SOURCE_FILE} NAME)
|
|
string(REPLACE "." "_" CONTENTS_NAME ${CONTENTS_NAME})
|
|
string(TOUPPER ${CONTENTS_NAME} CONTENTS_NAME)
|
|
|
|
FILE(READ ${SOURCE_FILE} line_contents)
|
|
|
|
# Replace double quotes with single quotes,
|
|
# as double quotes will be used to wrap the lines
|
|
STRING(REGEX REPLACE "\"" "'" line_contents "${line_contents}")
|
|
|
|
# CMake separates list elements with semicolons, but semicolons
|
|
# are used extensively in the shader code.
|
|
# Replace with a temporary marker, to be reverted later.
|
|
STRING(REGEX REPLACE ";" "{{SEMICOLON}}" line_contents "${line_contents}")
|
|
|
|
# Make every line an individual element in the CMake list.
|
|
STRING(REGEX REPLACE "\n" ";" line_contents "${line_contents}")
|
|
|
|
# Build the shader string, wrapping each line in double quotes.
|
|
foreach(line IN LISTS line_contents)
|
|
string(CONCAT CONTENTS "${CONTENTS}" \"${line}\\n\"\n)
|
|
endforeach()
|
|
|
|
# Revert the original semicolons in the source.
|
|
STRING(REGEX REPLACE "{{SEMICOLON}}" ";" CONTENTS "${CONTENTS}")
|
|
|
|
get_filename_component(OUTPUT_DIR ${HEADER_FILE} DIRECTORY)
|
|
make_directory(${OUTPUT_DIR})
|
|
configure_file(${INPUT_FILE} ${HEADER_FILE} @ONLY)
|